8690e6342c
Add fnmatch-gnu module. * gnulib/Makefile.in (aclocal_m4_deps): Add new files and remove one. * gnulib/configure.ac (AC_INIT): Use now import/memmem.c. * gnulib/aclocal.m4: Regenerate. * gnulib/config.in: Regenerate. * gnulib/configure: Regenerate. * gnulib/import/dummy.c: Remove. * gnulib/import/Makefile.am: Regenerate. * gnulib/import/Makefile.in: Likewise. * gnulib/import/m4/gnulib-cache.m4: Likewise. * gnulib/import/m4/gnulib-comp.m4: Likewise. * gnulib/import/alloca.c: New file. * gnulib/import/alloca.in.h: Likewise. * gnulib/import/config.charset: Likewise. * gnulib/import/fnmatch.c: Likewise. * gnulib/import/fnmatch.in.h: Likewise. * gnulib/import/fnmatch_loop.c: Likewise. * gnulib/import/localcharset.c: Likewise. * gnulib/import/localcharset.h: Likewise. * gnulib/import/m4/alloca.m4: Likewise. * gnulib/import/m4/codeset.m4: Likewise. * gnulib/import/m4/configmake.m4: Likewise. * gnulib/import/m4/fcntl-o.m4: Likewise. * gnulib/import/m4/fnmatch.m4: Likewise. * gnulib/import/m4/glibc21.m4: Likewise. * gnulib/import/m4/localcharset.m4: Likewise. * gnulib/import/m4/locale-fr.m4: Likewise. * gnulib/import/m4/locale-ja.m4: Likewise. * gnulib/import/m4/locale-zh.m4: Likewise. * gnulib/import/m4/mbrtowc.m4: Likewise. * gnulib/import/m4/mbsinit.m4: Likewise. * gnulib/import/m4/mbsrtowcs.m4: Likewise. * gnulib/import/m4/mbstate_t.m4: Likewise. * gnulib/import/m4/stdbool.m4: Likewise. * gnulib/import/m4/wchar_h.m4: Likewise. * gnulib/import/m4/wctype_h.m4: Likewise. * gnulib/import/m4/wint_t.m4: Likewise. * gnulib/import/mbrtowc.c: Likewise. * gnulib/import/mbsinit.c: Likewise. * gnulib/import/mbsrtowcs-impl.h: Likewise. * gnulib/import/mbsrtowcs-state.c: Likewise. * gnulib/import/mbsrtowcs.c: Likewise. * gnulib/import/ref-add.sin: Likewise. * gnulib/import/ref-del.sin: Likewise. * gnulib/import/stdbool.in.h: Likewise. * gnulib/import/streq.h: Likewise. * gnulib/import/strnlen1.c: Likewise. * gnulib/import/strnlen1.h: Likewise. * gnulib/import/verify.h: Likewise. * gnulib/import/wchar.in.h: Likewise. * gnulib/import/wctype.in.h: Likewise.
41 lines
1.4 KiB
Text
41 lines
1.4 KiB
Text
# mbstate_t.m4 serial 13
|
|
dnl Copyright (C) 2000-2002, 2008-2012 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
# From Paul Eggert.
|
|
|
|
# BeOS 5 has <wchar.h> but does not define mbstate_t,
|
|
# so you can't declare an object of that type.
|
|
# Check for this incompatibility with Standard C.
|
|
|
|
# AC_TYPE_MBSTATE_T
|
|
# -----------------
|
|
AC_DEFUN([AC_TYPE_MBSTATE_T],
|
|
[
|
|
AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS]) dnl for HP-UX 11.11
|
|
|
|
AC_CACHE_CHECK([for mbstate_t], [ac_cv_type_mbstate_t],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_PROGRAM(
|
|
[AC_INCLUDES_DEFAULT[
|
|
/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
|
|
<wchar.h>.
|
|
BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
|
|
included before <wchar.h>. */
|
|
#include <stddef.h>
|
|
#include <stdio.h>
|
|
#include <time.h>
|
|
#include <wchar.h>]],
|
|
[[mbstate_t x; return sizeof x;]])],
|
|
[ac_cv_type_mbstate_t=yes],
|
|
[ac_cv_type_mbstate_t=no])])
|
|
if test $ac_cv_type_mbstate_t = yes; then
|
|
AC_DEFINE([HAVE_MBSTATE_T], [1],
|
|
[Define to 1 if <wchar.h> declares mbstate_t.])
|
|
else
|
|
AC_DEFINE([mbstate_t], [int],
|
|
[Define to a type if <wchar.h> does not define.])
|
|
fi
|
|
])
|