8bc8f4bc00
strings. * ld.h: Added gettext-related includes and defines. * ldmain.c: Call setlocale, bindtextdomain, textdomain. * acconfig.h (ENABLE_NLS, HAVE_CATGETS, HAVE_GETTEXT, HAVE_STPCPY, HAVE_LC_MESSAGES): Define. * configure.in: Call CY_GNU_GETTEXT. Create po/Makefile.in and po/Makefile. Use AM_PROG_LEX. (TDIRS): AC_SUBST early on, to avoid having value split when it happens to cross line 90 of the generated sed script. * Makefile.am (SUBDIRS): New macro. (POTFILES): Likewise. (po/POTFILES.in): New target. (ld_new_LDADD): Added INTLLIBS. (ld_new_DEPENDENCIES): Added INTLDEPS. * po/Make-in, po/POTFILES.in, po/gas.pot: New files.
143 lines
3.1 KiB
Text
143 lines
3.1 KiB
Text
dnl Process this file with autoconf to produce a configure script
|
|
dnl
|
|
AC_PREREG(2.5)
|
|
AC_INIT(ldmain.c)
|
|
|
|
AC_CANONICAL_SYSTEM
|
|
|
|
AM_INIT_AUTOMAKE(ld, 2.9.1)
|
|
|
|
AM_PROG_LIBTOOL
|
|
|
|
AC_ARG_ENABLE(targets,
|
|
[ --enable-targets alternative target configurations],
|
|
[case "${enableval}" in
|
|
yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
|
|
;;
|
|
no) enable_targets= ;;
|
|
*) enable_targets=$enableval ;;
|
|
esac])dnl
|
|
AC_ARG_ENABLE(64-bit-bfd,
|
|
[ --enable-64-bit-bfd 64-bit support (on hosts with narrower word sizes)],
|
|
[case "${enableval}" in
|
|
yes) want64=true ;;
|
|
no) want64=false ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
|
|
esac],[want64=false])dnl
|
|
|
|
AM_CONFIG_HEADER(config.h:config.in)
|
|
|
|
if test -z "$target" ; then
|
|
AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
|
|
fi
|
|
if test -z "$host" ; then
|
|
AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
|
|
fi
|
|
|
|
# host-specific stuff:
|
|
|
|
AC_PROG_CC
|
|
AM_PROG_INSTALL
|
|
|
|
ALL_LINGUAS=
|
|
CY_GNU_GETTEXT
|
|
|
|
AM_CYGWIN32
|
|
AM_EXEEXT
|
|
|
|
AC_PROG_YACC
|
|
AM_PROG_LEX
|
|
|
|
AM_MAINTAINER_MODE
|
|
|
|
. ${srcdir}/configure.host
|
|
|
|
AC_SUBST(HDEFINES)
|
|
AC_SUBST(HOSTING_CRT0)
|
|
AC_SUBST(HOSTING_LIBS)
|
|
AC_SUBST(NATIVE_LIB_DIRS)
|
|
|
|
AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
|
|
AC_CHECK_FUNCS(sbrk)
|
|
AC_HEADER_DIRENT
|
|
|
|
BFD_BINARY_FOPEN
|
|
|
|
BFD_NEED_DECLARATION(strstr)
|
|
BFD_NEED_DECLARATION(free)
|
|
BFD_NEED_DECLARATION(sbrk)
|
|
BFD_NEED_DECLARATION(getenv)
|
|
|
|
# target-specific stuff:
|
|
|
|
all_targets=
|
|
EMUL=
|
|
all_emuls=
|
|
|
|
dnl We need to get an arbitrary number of tdir definitions into
|
|
dnl Makefile. We can't do it using AC_SUBST, because autoconf does
|
|
dnl not permit literal newlines in an AC_SUBST variables. So we use a
|
|
dnl file.
|
|
rm -f tdirs
|
|
|
|
for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
|
|
do
|
|
if test "$targ_alias" = "all"; then
|
|
all_targets=true
|
|
else
|
|
# Canonicalize the secondary target names.
|
|
result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ_alias 2>/dev/null`
|
|
if test -n "$result"; then
|
|
targ=$result
|
|
else
|
|
targ=$targ_alias
|
|
fi
|
|
|
|
. ${srcdir}/configure.tgt
|
|
|
|
if test "$targ" = "$target"; then
|
|
EMUL=$targ_emul
|
|
fi
|
|
|
|
for i in $targ_emul $targ_extra_emuls; do
|
|
case " $all_emuls " in
|
|
*" e${i}.o "*) ;;
|
|
*)
|
|
all_emuls="$all_emuls e${i}.o"
|
|
eval result=\$tdir_$i
|
|
test -z "$result" && result=$targ_alias
|
|
echo tdir_$i=$result >> tdirs
|
|
;;
|
|
esac
|
|
done
|
|
fi
|
|
done
|
|
|
|
AC_SUBST(EMUL)
|
|
|
|
TDIRS=tdirs
|
|
AC_SUBST_FILE(TDIRS)
|
|
|
|
dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
|
|
dnl target, and in those cases we should also build the 64 bit
|
|
dnl emulations.
|
|
if test x${all_targets} = xtrue; then
|
|
if test x${want64} = xtrue; then
|
|
EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
|
|
else
|
|
EMULATION_OFILES='$(ALL_EMULATIONS)'
|
|
fi
|
|
else
|
|
EMULATION_OFILES=$all_emuls
|
|
fi
|
|
AC_SUBST(EMULATION_OFILES)
|
|
|
|
if test x${enable_static} = xno; then
|
|
TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
|
|
else
|
|
TESTBFDLIB="../bfd/.libs/libbfd.a"
|
|
fi
|
|
AC_SUBST(TESTBFDLIB)
|
|
|
|
AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
|
|
[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])
|