84 lines
2.7 KiB
Text
84 lines
2.7 KiB
Text
dnl Process this file with autoconf to produce a configure script.
|
|
AC_PREREQ(2.59)
|
|
AC_INIT
|
|
AC_CONFIG_SRCDIR([gprof.c])
|
|
|
|
AC_CANONICAL_TARGET([])
|
|
AC_ISC_POSIX
|
|
|
|
changequote(,)dnl
|
|
BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[ ]*\([^ ]*\)[ ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
|
|
changequote([,])dnl
|
|
AM_INIT_AUTOMAKE(gprof, ${BFD_VERSION})
|
|
|
|
AM_PROG_LIBTOOL
|
|
|
|
dnl For simplicity, we use the BFD configuration file for most
|
|
dnl things. However, we also need our own configuration file for
|
|
dnl the automake PACKAGE and VERSION macros. We don't name it
|
|
dnl config.h, to avoid any possible confusion with the bfd config.h.
|
|
AC_CONFIG_HEADERS([gconfig.h:gconfig.in])
|
|
|
|
AC_PROG_CC
|
|
AC_PROG_INSTALL
|
|
|
|
AC_CHECK_FUNCS(setmode)
|
|
|
|
ALL_LINGUAS="fr tr sv es id da pt_BR de vi rw"
|
|
CY_GNU_GETTEXT
|
|
|
|
AM_MAINTAINER_MODE
|
|
AC_EXEEXT
|
|
|
|
AC_CHECK_HEADERS(sys/gmon_out.h)
|
|
|
|
AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
|
|
AC_CACHE_VAL(gprof_cv_decl_getopt_unistd_h,
|
|
[AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
|
|
gprof_cv_decl_getopt_unistd_h=yes, gprof_cv_decl_getopt_unistd_h=no)])
|
|
AC_MSG_RESULT($gprof_cv_decl_getopt_unistd_h)
|
|
if test $gprof_cv_decl_getopt_unistd_h = yes; then
|
|
AC_DEFINE([HAVE_DECL_GETOPT], 1,
|
|
[Is the prototype for getopt in <unistd.h> in the expected format?])
|
|
fi
|
|
|
|
build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
|
|
|
|
AC_ARG_ENABLE(werror,
|
|
[ --enable-werror treat compile warnings as errors],
|
|
[case "${enableval}" in
|
|
yes | y) ERROR_ON_WARNING="yes" ;;
|
|
no | n) ERROR_ON_WARNING="no" ;;
|
|
*) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
|
|
esac])
|
|
|
|
# Enable -Werror by default, suppressing it only for --disable-werror
|
|
# or --disable-build-warnings.
|
|
if test "${ERROR_ON_WARNING}" != no
|
|
then
|
|
build_warnings="$build_warnings -Werror"
|
|
fi
|
|
|
|
AC_ARG_ENABLE(build-warnings,
|
|
[ --enable-build-warnings Enable build-time compiler warnings if gcc is used],
|
|
[case "${enableval}" in
|
|
yes) ;;
|
|
no) build_warnings="-w";;
|
|
,*) t=`echo "${enableval}" | sed -e "s/,/ /g"`
|
|
build_warnings="${build_warnings} ${t}";;
|
|
*,) t=`echo "${enableval}" | sed -e "s/,/ /g"`
|
|
build_warnings="${t} ${build_warnings}";;
|
|
*) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
|
|
esac
|
|
if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
|
|
echo "Setting warning flags = $build_warnings" 6>&1
|
|
fi])dnl
|
|
WARN_CFLAGS=""
|
|
if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
|
|
WARN_CFLAGS="${build_warnings}"
|
|
fi
|
|
AC_SUBST(WARN_CFLAGS)
|
|
|
|
AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
|
|
AC_CONFIG_COMMANDS([default],[[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]],[[]])
|
|
AC_OUTPUT
|