f6a88844c3
This patch introduces a new M4 macro GDB_AC_TRANSFORM to avoid repeating the common idiom which is the transformation of target program names, i.e. from gdb to sparc64-linux-gnu-gdb. It also makes gdb/configure.ac and gdb/testsuite/configure.ac to use the new macro. gdb/ChangeLog: 2015-02-18 Jose E. Marchesi <jose.marchesi@oracle.com> * configure: Regenerated. * configure.ac: Use GDB_AC_TRANSFORM. * Makefile.in (aclocal_m4_deps): Added transform.m4. * acinclude.m4: sinclude transform.m4. * transform.m4: New file. (GDB_AC_TRANSFORM): New macro. gdb/testsuite/ChangeLog: 2015-02-18 Jose E. Marchesi <jose.marchesi@oracle.com> * configure: Regenerated. * configure.ac: Use GDB_AC_TRANSFORM. * aclocal.m4: sinclude ../transform.m4.
120 lines
3.7 KiB
Text
120 lines
3.7 KiB
Text
# -*- Autoconf -*-
|
|
# Process this file with autoconf to produce a configure script.
|
|
|
|
# Copyright 2002-2015 Free Software Foundation, Inc.
|
|
#
|
|
# This program is free software; you can redistribute it and/or modify
|
|
# it under the terms of the GNU General Public License as published by
|
|
# the Free Software Foundation; either version 3 of the License, or
|
|
# (at your option) any later version.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
# GNU General Public License for more details.
|
|
#
|
|
# You should have received a copy of the GNU General Public License
|
|
# along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
AC_PREREQ(2.59)
|
|
AC_INIT(gdb.base)
|
|
|
|
AC_CANONICAL_BUILD
|
|
AC_CANONICAL_HOST
|
|
AC_CANONICAL_TARGET
|
|
|
|
ACX_NONCANONICAL_TARGET
|
|
|
|
# Check for the 'make' the user wants to use.
|
|
AC_CHECK_PROGS(MAKE, make)
|
|
MAKE_IS_GNU=
|
|
case "`$MAKE --version 2>&1 | sed 1q`" in
|
|
*GNU*)
|
|
MAKE_IS_GNU=yes
|
|
;;
|
|
esac
|
|
AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes)
|
|
AC_PROG_MAKE_SET
|
|
|
|
# Enable gdbtk.
|
|
AC_ARG_ENABLE(gdbtk,
|
|
[ --enable-gtk enable gdbtk graphical user interface (GUI)],,
|
|
[if test -d $srcdir/../gdbtk && test -d $srcdir/gdb.gdbtk; then
|
|
enable_gdbtk=yes
|
|
else
|
|
enable_gdbtk=no
|
|
fi])
|
|
# We unconditionally disable gdbtk tests on selected platforms.
|
|
case $host_os in
|
|
go32* | windows*)
|
|
enable_gdbtk=no ;;
|
|
esac
|
|
|
|
# Add gdbtk tests when appropriate.
|
|
if test $enable_gdbtk = yes; then
|
|
AC_CONFIG_SUBDIRS(gdb.gdbtk)
|
|
fi
|
|
|
|
# Enable shared libraries.
|
|
AC_ARG_ENABLE(shared,
|
|
[ --enable-shared build shared libraries [deault=yes]],,
|
|
enable_shared=yes)
|
|
|
|
# If we have shared libraries, try to set RPATH_ENVVAR reasonably,
|
|
# such that we can find the shared libraries in the build tree.
|
|
if test $enable_shared = no; then
|
|
# The variable `RPATH_ENVVAR' itself is not likely to be used on any
|
|
# platform.
|
|
RPATH_ENVVAR=RPATH_ENVVAR
|
|
else
|
|
# The variable `LD_LIBRARY_PATH' is used on most platforms.
|
|
RPATH_ENVVAR=LD_LIBRARY_PATH
|
|
# The following exceptions are taken from Libtool 1.4.3.
|
|
case $host_os in
|
|
aix*)
|
|
if test $host_cpu != ia64; then
|
|
RPATH_ENVVAR=LIBPATH
|
|
fi ;;
|
|
darwin* | rhapsody*)
|
|
RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
|
|
hpux*)
|
|
RPATH_ENVVAR=SHLIB_PATH ;;
|
|
esac
|
|
fi
|
|
AC_SUBST(RPATH_ENVVAR)
|
|
|
|
AC_CHECK_HEADERS(pthread.h)
|
|
|
|
AC_EXEEXT
|
|
|
|
if test "${build}" = "${host}" -a "${host}" = "${target}"; then
|
|
case "${host}" in
|
|
*gnu*)
|
|
EXTRA_RULES=read1
|
|
;;
|
|
esac
|
|
fi
|
|
AC_SUBST(EXTRA_RULES)
|
|
|
|
# Transform the name of some programs and generate the lib/pdtrace
|
|
# test tool.
|
|
AC_ARG_PROGRAM
|
|
GDB_AC_TRANSFORM(strip, STRIP_TRANSFORM_NAME)
|
|
GDB_AC_TRANSFORM(readelf, READELF_TRANSFORM_NAME)
|
|
GDB_AC_TRANSFORM(as, GAS_TRANSFORM_NAME)
|
|
GDB_AC_TRANSFORM(nm, NM_TRANSFORM_NAME)
|
|
AC_CONFIG_FILES([lib/pdtrace], [chmod +x lib/pdtrace])
|
|
|
|
AC_OUTPUT([Makefile \
|
|
gdb.ada/Makefile \
|
|
gdb.arch/Makefile gdb.asm/Makefile gdb.base/Makefile gdb.btrace/Makefile \
|
|
gdb.cell/Makefile gdb.compile/Makefile gdb.cp/Makefile gdb.disasm/Makefile \
|
|
gdb.dwarf2/Makefile gdb.dlang/Makefile gdb.fortran/Makefile gdb.gdb/Makefile \
|
|
gdb.go/Makefile gdb.server/Makefile gdb.java/Makefile \
|
|
gdb.hp/Makefile gdb.hp/gdb.objdbg/Makefile gdb.hp/gdb.base-hp/Makefile \
|
|
gdb.hp/gdb.aCC/Makefile gdb.hp/gdb.compat/Makefile \
|
|
gdb.hp/gdb.defects/Makefile gdb.guile/Makefile gdb.linespec/Makefile \
|
|
gdb.mi/Makefile gdb.modula2/Makefile gdb.multi/Makefile \
|
|
gdb.objc/Makefile gdb.opencl/Makefile gdb.opt/Makefile gdb.pascal/Makefile \
|
|
gdb.perf/Makefile gdb.python/Makefile gdb.reverse/Makefile gdb.stabs/Makefile \
|
|
gdb.threads/Makefile gdb.trace/Makefile gdb.xml/Makefile])
|