9b30624b65
The ptrace args/return types detection doesn't work properly in C++ mode, on non-GNU/Linux hosts. For example, on gcc70 (NetBSD 5.1), where the prototype is: int ptrace(int, __pid_t, void*, int); configure misdetects it as: $ grep PTRACE_TYPE config.h #define PTRACE_TYPE_ARG1 int #define PTRACE_TYPE_ARG3 int * #define PTRACE_TYPE_ARG4 int /* #undef PTRACE_TYPE_ARG5 */ #define PTRACE_TYPE_RET int resulting in: ../../src/gdb/amd64bsd-nat.c: In function 'void amd64bsd_fetch_inferior_registers(target_ops*, regcache*, int)': ../../src/gdb/amd64bsd-nat.c:56: warning: dereferencing type-punned pointer will break strict-aliasing rules ../../src/gdb/amd64bsd-nat.c: In function 'void amd64bsd_store_inferior_registers(target_ops*, regcache*, int)': ../../src/gdb/amd64bsd-nat.c:104: warning: dereferencing type-punned pointer will break strict-aliasing rules ../../src/gdb/amd64bsd-nat.c:110: warning: dereferencing type-punned pointer will break strict-aliasing rules We could address this [1], however despite ptrace.m4's claim: # Needs to be tested in C++ mode, to detect whether we need to cast # the first argument to enum __ptrace_request. it appears that there's actually no need to test in C++ mode. Always running the ptrace tests in C mode works just the same on GNU/Linux. I remember experimenting with several different ways to handle the original issue back then, and maybe that was needed in some other attempt and then I didn't realize it ended up not really necessary. Confirmed that this fixes the NetBSD 5.1 C++ build, and confirmed that C and C++ builds on Fedora 23 are unaffected. [1] - https://sourceware.org/ml/gdb-patches/2016-04/msg00374.html gdb/ChangeLog: 2016-04-18 Pedro Alves <palves@redhat.com> * ptrace.m4 (GDB_AC_PTRACE): Don't run tests in C++ mode. * configure: Regenerate. gdb/gdbserver/ChangeLog: 2016-04-18 Pedro Alves <palves@redhat.com> * configure: Regenerate.
94 lines
3.3 KiB
Text
94 lines
3.3 KiB
Text
dnl Copyright (C) 2012-2016 Free Software Foundation, Inc.
|
|
dnl
|
|
dnl This file is part of GDB.
|
|
dnl
|
|
dnl This program is free software; you can redistribute it and/or modify
|
|
dnl it under the terms of the GNU General Public License as published by
|
|
dnl the Free Software Foundation; either version 3 of the License, or
|
|
dnl (at your option) any later version.
|
|
dnl
|
|
dnl This program is distributed in the hope that it will be useful,
|
|
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
dnl GNU General Public License for more details.
|
|
dnl
|
|
dnl You should have received a copy of the GNU General Public License
|
|
dnl along with this program. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
dnl Check the return and argument types of ptrace.
|
|
|
|
AC_DEFUN([GDB_AC_PTRACE],
|
|
[
|
|
|
|
AC_CHECK_HEADERS([sys/ptrace.h ptrace.h])
|
|
|
|
gdb_ptrace_headers='
|
|
#include <sys/types.h>
|
|
#if HAVE_SYS_PTRACE_H
|
|
# include <sys/ptrace.h>
|
|
#endif
|
|
#if HAVE_UNISTD_H
|
|
# include <unistd.h>
|
|
#endif
|
|
'
|
|
# There is no point in checking if we don't have a prototype.
|
|
AC_CHECK_DECLS(ptrace, [], [
|
|
: ${gdb_cv_func_ptrace_ret='int'}
|
|
: ${gdb_cv_func_ptrace_args='int,int,long,long'}
|
|
], $gdb_ptrace_headers)
|
|
# Check return type. Varargs (used on GNU/Linux) conflict with the
|
|
# empty argument list, so check for that explicitly.
|
|
AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret,
|
|
AC_TRY_COMPILE($gdb_ptrace_headers,
|
|
[extern long ptrace (enum __ptrace_request, ...);],
|
|
gdb_cv_func_ptrace_ret='long',
|
|
AC_TRY_COMPILE($gdb_ptrace_headers,
|
|
[extern int ptrace ();],
|
|
gdb_cv_func_ptrace_ret='int',
|
|
gdb_cv_func_ptrace_ret='long')))
|
|
AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret,
|
|
[Define as the return type of ptrace.])
|
|
# Check argument types.
|
|
AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [
|
|
AC_TRY_COMPILE($gdb_ptrace_headers,
|
|
[extern long ptrace (enum __ptrace_request, ...);],
|
|
[gdb_cv_func_ptrace_args='enum __ptrace_request,int,long,long'],[
|
|
for gdb_arg1 in 'int' 'long'; do
|
|
for gdb_arg2 in 'pid_t' 'int' 'long'; do
|
|
for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do
|
|
for gdb_arg4 in 'int' 'long' 'void *'; do
|
|
AC_TRY_COMPILE($gdb_ptrace_headers, [
|
|
extern $gdb_cv_func_ptrace_ret
|
|
ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4);
|
|
], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4";
|
|
break 4;])
|
|
for gdb_arg5 in 'int *' 'int' 'long'; do
|
|
AC_TRY_COMPILE($gdb_ptrace_headers, [
|
|
extern $gdb_cv_func_ptrace_ret
|
|
ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5);
|
|
], [
|
|
gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5";
|
|
break 5;])
|
|
done
|
|
done
|
|
done
|
|
done
|
|
done
|
|
# Provide a safe default value.
|
|
: ${gdb_cv_func_ptrace_args='int,int,long,long'}
|
|
])])
|
|
ac_save_IFS=$IFS; IFS=','
|
|
set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'`
|
|
IFS=$ac_save_IFS
|
|
shift
|
|
AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG1, $[1],
|
|
[Define to the type of arg 1 for ptrace.])
|
|
AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3],
|
|
[Define to the type of arg 3 for ptrace.])
|
|
AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4],
|
|
[Define to the type of arg 4 for ptrace.])
|
|
if test -n "$[5]"; then
|
|
AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5],
|
|
[Define to the type of arg 5 for ptrace.])
|
|
fi
|
|
])
|