old-cross-binutils/gdb/testsuite/gdb.ada/task_bp.exp

# Copyright 2011-2012 Free Software Foundation, Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

load_lib "ada.exp"

set testdir "task_bp"
set testfile "${testdir}/foo"
set srcfile ${srcdir}/${subdir}/${testfile}.adb
set binfile ${objdir}/${subdir}/${testfile}

file mkdir ${objdir}/${subdir}/${testdir}
if {[gdb_compile_ada "${srcfile}" "${binfile}" executable [list debug]] != "" } {
  return -1
}

# Insert a breakpoint at LOC, and run the program expecting us to
# reach that breakpoint.
#
# LOC is expected to be a linespec referencing the body of task
# Pck.Dummy_Task (the purpose is to test all the variations of
# these equivalent linespecs).
#
# MSG is just a string that's used to qualify the name of the tests
# that are executed inside that procedure.  The purpose to be able
# to call that function multiple times with the same linespec, in
# order to test one given linespec under multiple conditions.

proc test_bp { loc msg } {
   gdb_test "break $loc" \
     "Breakpoint \[0-9\]+ at 0x\[0-9a-fA-F\]+: file .*pck.adb, line \[0-9\]+\." \
     "break $loc - $msg"

   gdb_run_cmd
   gdb_test "" \
     "Breakpoint \[0-9\]+, pck\\.dummy_task (.*)" \
     "run to $loc - $msg"
}

set all_linespecs { "pck.dummy_task" "dummy_task"
                    "pck.adb:pck.dummy_task" "pck.adb:dummy_task"}

# First, test the linespecs when the associated symtab hasn't been
# expanded yet.

foreach linespec $all_linespecs {
    clean_restart ${testfile}
    test_bp $linespec "from psymtab"
}

# Now, do the same, but with the associated symtab already expanded.

foreach linespec $all_linespecs {
    clean_restart ${testfile}
    gdb_test "list pck.adb:1" ".*" "expanding symtab for $linespec"
    test_bp $linespec "from full symtab"
}