add kodi joyn addon

flake.nix

@@ -252,6 +252,8 @@
                   art-lotte
                   art-lotte-bgs-nsfw
                   art-lotte-bgs-sfw
+                  kodi-joyn
+                  kodi-pydes
                   package-updater
                   ;
               };

packages/default.nix

@@ -2,5 +2,7 @@ self: super: {
   art-lotte = self.callPackage ./art/lotte { };
   art-lotte-bgs-nsfw = self.callPackage ./art/lotte/bgs-nsfw.nix { };
   art-lotte-bgs-sfw = self.callPackage ./art/lotte/bgs-sfw.nix { };
+  kodi-joyn = self.kodiPackages.callPackage ./kodi/joyn { };
+  kodi-pydes = self.kodiPackages.callPackage ./kodi/pydes { };
   package-updater = self.callPackage ./updater.nix { };
 }

packages/kodi/joyn/default.nix

@@ -0,0 +1,32 @@
+{
+  buildKodiAddon,
+  fetchFromGitHub,
+  inputstream-adaptive,
+  inputstreamhelper,
+  kodi-pydes,
+  lib,
+  simplejson,
+}:
+let
+  srcInfo = lib.importJSON ./source.json;
+in
+buildKodiAddon {
+  pname = "Joyn";
+  namespace = "plugin.video.joyn";
+  version = "2.3.1.10";
+  src = fetchFromGitHub {
+    owner = "knaerzche";
+    repo = "plugin.video.joyn";
+    inherit (srcInfo) rev sha256;
+  };
+  propagatedBuildInputs = [
+    inputstream-adaptive
+    inputstreamhelper
+    kodi-pydes
+    simplejson
+  ];
+  meta = {
+    license = lib.licenses.gpl2;
+    description = "Watch VOD content und Live TV provided by Joyn";
+  };
+}

packages/kodi/joyn/source.json

@@ -0,0 +1,12 @@
+{
+    "url": "https://github.com/knaerzche/plugin.video.joyn",
+    "rev": "0954c40d20fe4c956c45519993f0dfdc0debade2",
+    "date": "2020-09-04T17:17:52+02:00",
+    "path": "/nix/store/1c49y966arnakcna3nb55fpfik0rsysq-plugin.video.joyn",
+    "sha256": "1wkn03j0mwlbnnl0zzr74pw3z4z2r76130rana7jdmc79fqxld53",
+    "hash": "sha256-ozTasUuH1SaPsiqDEczJ4pM/+CUn/w+otYvyCuQAdvI=",
+    "fetchLFS": false,
+    "fetchSubmodules": false,
+    "deepClone": false,
+    "leaveDotGit": false
+}

packages/kodi/joyn/updater.nix

@@ -0,0 +1,19 @@
+{
+  nix-prefetch-git,
+  curl,
+  jq,
+  lib,
+}:
+let
+  srcInfo = lib.importJSON ./source.json;
+in
+''
+  echo "kodi-joyn: Checking for updates"
+  CURRENT_COMMIT=$(${curl}/bin/curl https://api.github.com/repos/knaerzche/plugin.video.joyn/commits | ${jq}/bin/jq -r '.[0].sha')
+  KNOWN_COMMIT=${srcInfo.rev}
+  if [ $CURRENT_COMMIT != $KNOWN_COMMIT ]; then
+    echo "kodi-joyn: Updating from $KNOWN_COMMIT to $CURRENT_COMMIT"
+    ${nix-prefetch-git}/bin/nix-prefetch-git https://github.com/knaerzche/plugin.video.joyn | ${jq}/bin/jq > packages/kodi/joyn/source.json
+  fi
+  echo "kodi-joyn: Done"
+''

packages/kodi/pydes/addon.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
+<addon id="script.module.pydes" name="pyDes" version="2.0.1" provider-name="Todd Whiteman">
+  <requires>
+    <import addon="xbmc.python" version="2.1.0"/>
+  </requires>
+  <extension point="xbmc.python.module"
+             library="lib" />
+  <extension point="xbmc.addon.metadata">
+    <summary lang="en">A pure python module which implements the DES and Triple-DES encryption algorithms.</summary>
+    <website>http://twhiteman.netfirms.com/des.html</website> 
+    <license>MIT</license> 
+    <platform>all</platform> 
+    <source>http://sourceforge.net/projects/pydes/</source> 
+  </extension>
+</addon>

packages/kodi/pydes/default.nix

@@ -0,0 +1,11 @@
+{ callPackage, buildKodiAddon }:
+let
+  src = callPackage ./source.nix { };
+in
+buildKodiAddon {
+  pname = "pyDes";
+  namespace = "script.module.pydes";
+  version = "2.0.1";
+  inherit src;
+  inherit (src) meta;
+}

packages/kodi/pydes/source.json

@@ -0,0 +1,12 @@
+{
+    "url": "https://github.com/twhiteman/pyDes",
+    "rev": "e988a5ffc9abb8010fc75dba54904d1c5dbe83db",
+    "date": "2019-01-07T17:12:32-08:00",
+    "path": "/nix/store/avhx558pnxzlzl4ww1xrzkl08qcp19pm-pyDes",
+    "sha256": "0sic8wbyk5azb4d4m6zbc96lfqcw8s2pzcv9nric5yqc751613ww",
+    "hash": "sha256-nI9gQjkM+8Jitmmzf4VGnGFHTWLrm0oaWV+V6RdHLGo=",
+    "fetchLFS": false,
+    "fetchSubmodules": false,
+    "deepClone": false,
+    "leaveDotGit": false
+}

packages/kodi/pydes/source.nix

@@ -0,0 +1,29 @@
+{
+  stdenvNoCC,
+  fetchFromGitHub,
+  lib,
+}:
+let
+  srcInfo = lib.importJSON ./source.json;
+  src = fetchFromGitHub {
+    owner = "twhiteman";
+    repo = "pyDes";
+    inherit (srcInfo) rev sha256;
+  };
+in
+stdenvNoCC.mkDerivation {
+  pname = "kodi-pydes";
+  version = srcInfo.date;
+  inherit src;
+  dontUnpack = true;
+  dontBuild = true;
+  installPhase = ''
+    mkdir -p $out/lib
+    cp $src/pyDes.py $out/lib
+    cp ${./addon.xml} $out/addon.xml
+  '';
+  meta = {
+    license = lib.licenses.mit;
+    description = "A pure python module which implements the DES and Triple-DES encryption algorithms.";
+  };
+}

packages/kodi/pydes/updater.nix

@@ -0,0 +1,19 @@
+{
+  nix-prefetch-git,
+  curl,
+  jq,
+  lib,
+}:
+let
+  srcInfo = lib.importJSON ./source.json;
+in
+''
+  echo "kodi-pydes: Checking for updates"
+  CURRENT_COMMIT=$(${curl}/bin/curl https://api.github.com/repos/twhiteman/pyDes/commits | ${jq}/bin/jq -r '.[0].sha')
+  KNOWN_COMMIT=${srcInfo.rev}
+  if [ $CURRENT_COMMIT != $KNOWN_COMMIT ]; then
+    echo "kodi-pydes: Updating from $KNOWN_COMMIT to $CURRENT_COMMIT"
+    ${nix-prefetch-git}/bin/nix-prefetch-git https://github.com/twhiteman/pyDes | ${jq}/bin/jq > packages/kodi/pydes/source.json
+  fi
+  echo "kodi-pydes: Done"
+''

packages/kodi/updater.nix

@@ -0,0 +1,8 @@
+{
+  lib,
+  callPackage,
+}:
+lib.concatMapStringsSep "\n" (f: callPackage "${f}/updater.nix" { }) [
+  ./joyn
+  ./pydes
+]

packages/updater.nix

@@ -6,7 +6,10 @@
   nix,
 }:
 let
-  script = lib.concatMapStringsSep "\n" (f: callPackage "${f}/updater.nix" { }) [ ./art ];
+  script = lib.concatMapStringsSep "\n" (f: callPackage "${f}/updater.nix" { }) [
+    ./art
+    ./kodi
+  ];
 in
 writeScriptBin "updater" ''
   #!${bash}/bin/bash

programs/desktop/kodi/default.nix

@@ -9,6 +9,7 @@
       kodiPkgs: with kodiPkgs; [
         jellyfin
         jellycon
+        pkgs.kodi-joyn
       ]
     ))
   ];